Examples.Flex 2: Enhancing the Blog Reader Example.

In the Live docs you might have read about Retrieve and Display Data. Here I've enhanced the same MXML by the following

• The LinkButton hidden until the datagrid change event is fired.
• Enabled the Data Tips for 'Posts' column to show tool tips text on roll over.
• Made it a scalable layout by using constraint-based layout.

Here is the MXML code, I've highlighted the changes by bold, compare it with the original, compile and see for your self

<?xml version="1.0" encoding="UTF-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="feedRequest.send()" minHeight="360" minWidth="500">
 <mx:HTTPService id="feedRequest" url="http://weblogs.macromedia.com/mchotin/index.xml" useProxy="false"/>
 <mx:Panel left="10" top="10" bottom="10" right="10" layout="absolute" title="BlogReader ({feedRequest.lastResult.rss.channel.title})">
  <mx:DataGrid id="dgPosts" left="20" right="20" top="20" bottom="125" dataProvider="{feedRequest.lastResult.rss.channel.item}" change="openLinkButton.visible=true">
   <mx:columns>
    <mx:DataGridColumn headerText="Posts" dataField="title" showDataTips="true"/>
    <mx:DataGridColumn headerText="Date" dataField="pubDate"/>
   </mx:columns>
  </mx:DataGrid>
  <mx:TextArea left="20" right="20" bottom="46" height="75" htmlText="{dgPosts.selectedItem.description}"/>
  <mx:LinkButton id="openLinkButton" right="20" bottom="20" label="Read Full Post" click="navigateToURL(new URLRequest(dgPosts.selectedItem.link));" visible="false"/>
 </mx:Panel>
</mx:Application>

Tips.AMFPHP: Sending Arrays with offset Index.

$arr =array(5=>5);

var arr:Array= [];
arr[5]=5;

arr=[null, null, null, null, null, 5];

$arr=array(NULL, NULL, NULL, NULL, NULL, 5);

Code.Flash 9: Webcam Motion Detection using AS3 - Source Released.

Demo.Flash 9: Webcam Motion Detection using AS3.

Examples.Flash 9: Understanding AMF0 and AS3 Array.

<?
class AS3ArrayTest{
  function AS3ArrayTest(){
    @include_once("AS3ArrayTest.methodTable.php");
  }
  /**Converts the given data to String and returns it
  *@param Data Any, Data that needs to be converted
  *@access remote
  *@returns String
  */
  function convertToString($data){
    $str = "PHP dataType: ".gettype($data)."\n";
    $str .= print_r($data, true); 
    return $str;
  }
}
?>

import flash.net.Responder;
var conn : RemotingConnection = new RemotingConnection( "http://localhost/amfphp/gateway.php");
//
var simpleArray=[9,8,7];
conn.call( "AS3ArrayTest.convertToString", new Responder(onResult1,null), simpleArray);
//
var associativeArray=[1,2,3]
associativeArray['key']='value';
conn.call( "AS3ArrayTest.convertToString", new Responder(onResult2,null), associativeArray);
//
var object ={key:'value'}
conn.call( "AS3ArrayTest.convertToString", new Responder(onResult3,null), object);
//
var objectWithArray ={key:'value', simpleArray:[4,5]}
conn.call( "AS3ArrayTest.convertToString", new Responder(onResult4,null), objectWithArray);
//
function onResult1( result  ) : void{
    t1_txt.text=result
}
//
function onResult2( result  ) : void{
    t2_txt.text=result
}
//
function onResult3( result  ) : void{
    t3_txt.text=result
}
//
function onResult4( result  ) : void{
    t4_txt.text=result
} 

• If you need to send index based Array, no problem use Array
• If you need to send key value pairs, use Object instead
• If you can ignore the 'length' property on the server side you may still use Associative Array
• Else you may keep the simple Array as one of the elements of your Object and send the Object

Bug.AMFPHP: Service Browser does not handle method table 'arguments' metadata defined as key value pairs.

$keyIndex = 0;	
	foreach($arguments as $key => $name) {
			if(is_array($name)){
				$name = $key;
				$key = $keyIndex ++;
			}
			$method .= '<tr class="caption"><td class="key">' . $name . '</td><td><input class="inputbox" type="text" name="' . $methodName . '_arguments[]" maxlength="65535" value="'. htmlspecialchars(strip($_POST[$methodName . "_arguments"][$key])) . '"/></td></tr>'."\n";
}

News.AMFPHP: Introducing ObjectStore.

What is ObjectStore?
Object Store is a service for creating, managing and accessing objects on the server. It is a light weight alternative to keeping XML data on the server.

How do we compare ObjectStore with RemoteSharedObject?
ObjectStore is similar to RemoteSharedObject in terms of storing data on the server, but ObjectStore does not poll (automatically refresh) data and does not fire events on change, although this can be achieved by writing your own Actionscript.

Do we need AMFPHP to use ObjectStore?
AMFPHP is needed only when you need to send and receive the data from flash through remoting, All the data access api is available to PHP.

What are the data types supported by ObjectStore?
following data types are supported

How do we access data in ObjectStore?
you can access object using a combination of file path and object path, say for example "myfolder/subfolder/myobject.childobject.property" ('/' is used to indicate the folders and '.' is used to indicate the objects) here "myfolder/subfolder/myobject" is the file path and "childobject.property" is the object path.

I'm planning to create a new object, which one should I prefer to use file path or object path?
consider file paths like the name spaces in as2 / package in as3. Use them to avoid name clashes and to organize your objects wisely. object path is the actual object structure which can be compared to properties of the classes in Actionscript. Lengthy object path is going to result in bigger object files on the server, so try to keep it as file path as whenever possible.

Where can I get ObjectStore?
You will be able to download ObjectStore from my blog soon, keep watching this blog for more updates :)

How much it costs?
It will be free for both noncommercial and commercial use.

more info to follow...

Examples.Flash 9: How to load data from a remote URL?

package
{
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.events.Event;
	public class DataLoadingTest
	{
		private var urlString : String = "http://weblogs.macromedia.com/mxna/";
		private var dataLoader : URLLoader;
		public function DataLoadingTest ()
		{
			dataLoader = new URLLoader ();
			dataLoader.addEventListener ("complete", onDataLoad);
			dataLoader.addEventListener ("securityError", onSecurityError);
			dataLoader.load (new URLRequest (urlString));
		}
		private function onDataLoad (event : Event) : void
		{
			trace ("Raw Data : " + event.target.data);
		}
		private function onSecurityError (event : Event) : void
		{
			trace ("Security Error : " + event);
		}
	}
}
/*
//Usage:-
//place the following code in the first frame
var dlt:DataLoadingTest=new DataLoadingTest();
*/ 

Examples.Flash 9: Porting XMLHighlighter class to ActionScript 3.

• XML object in ActionScript 3 is different (It is ECMAScript for XML (E4X)).
• For backward compatibility we have XMLDocument class which is equalent to XML in Actionscript 3.
• In ActionScript 3 we need to keep the class inside Package container.

/*
************************************************************
Developed by R.Arul Kumaran [arul@shockwave-india.com]     *
for more code keep visiting [www.shockwave-india.com/blog] *
************************************************************
version 1.0 Last updated on 4 July, 2006
*/
/*
XMLHighlighter for ActionScript3 generates color highlighted pretty printed HTML code
*/
package 
{
	import flash.xml.*
	class XMLDocumentHighlighter 
	{
		public static var useCDATA : Boolean = true;
		//_c: color string list
		private static var _c : Object = {
			tag : '0000FF', att : 'FF0000', txt : '000000', tgt : '990000'
		};
		//_fTag: get font begin tag
		private static function _fTag (clr : String, content : String)
		{
			return "<font color='#" + clr + "'>" + content;
		}
		// _tf: font tag close string
		private static var _tf : String = "</font>";
		// public function
		public static function highlight (x : XMLDocument) : String 
		{
			//var x:XML;
			var ignoreWhite = x.ignoreWhite;
			var s : String = _fTag (_c.tag, '');
			x.ignoreWhite = true;
			if (x.nodeName == undefined)
			{
				if (x.xmlDecl != undefined)
				{
					s += x.createTextNode (x.xmlDecl) + '\r';
				}
				if (x.docTypeDecl != undefined)
				{
					s += x.createTextNode (x.docTypeDecl) + '\r';
				}
				s += _getHStr (x.firstChild, '', '');
			} else 
			{
				s += _getHStr (x, '', '');
			}
			x.ignoreWhite = ignoreWhite;
			return "<pre>" + s + _tf + "</pre>";
		}
		private static function _getHStr (x, tab : String, r : String) : String 
		{
			var s : String = '';
			switch (x.nodeType)
			{
				//TEXT_NODE
				case 3 :
				//Is it a CDATA Node?
				var xt : String = x.toString ();
				if (useCDATA && (x.nodeValue.indexOf ('<') != - 1 || x.nodeValue.indexOf ('>') != - 1))
				{
					s = "&lt;![CDATA[" + _fTag (_c.txt, '<b>' + xt + '</b>') + _tf + "]]&gt;";
				} else 
				{
					s = _fTag (_c.txt, '<b>' + xt.split ('&').join ('&amp;') + '</b>') + _tf;
				}
				break;
				//ELEMENT_NODE
				case 1 :
				default :
				s = r + tab + '&lt;' + _fTag (_c.tgt, x.nodeName) + _tf;
				for (var v in x.attributes)
				{
					s += _fTag (_c.tgt, " " + v) + _tf + "=&quot;" + _fTag (_c.att, x.attributes [v]) + _tf + "&quot;";
				}
				if (x.firstChild == null)
				{
					s += "/&gt;";
				} else 
				{
					s += "&gt;" + _getHStr (x.firstChild, tab + "\t", "\r");
					if (x.lastChild.nodeType == 3)
					{
						s += "&lt;/";
					} else 
					{
						s += '\r' + tab + "&lt;/";
					}
					s += _fTag (_c.tgt, x.nodeName) + _tf + "&gt;";
				}
			}
			if (x.nextSibling != null)
			{
				s += _getHStr (x.nextSibling, tab, r);
			}
			return s;
		}
	}
}
/*
//Usage:-
//copy this as file to the same folder as your FLA
//Usage Example:
var my_xml:XMLDocument=new XMLDocument('<a><b><c/></b></a>');
trace(XMLDocumentHighlighter.highlight(my_xml));
 
//trace output :
 
<pre><font color='#0000FF'>&lt;<font color='#990000'>a</font>&gt;
	&lt;<font color='#990000'>b</font>&gt;
		&lt;<font color='#990000'>c</font>/&gt;
	&lt;/<font color='#990000'>b</font>&gt;
&lt;/<font color='#990000'>a</font>&gt;</font></pre>
 
 
*/ 

Code.PHP: Removing Byte Order Mark (BOM) from the given string.

function removeBOM($str=''){
	if(strpos($str, "»")==1)$str=substr($str, 3);
	return $str;
}
/*
//Usage:-
$text = removeBOM(file_get_contents("myData.xml",true));
*/

footnote:-
Also check the recent entries and feel free to add your comments. I need your comments to improve this blog